Новый табель см. в публикации>>

Скачать файл "Табель рабочего времени" в excel

Форма Табеля взята с КонсультантПлюс, немного переделана для улучшения визуального восприятия, данные табеля перенесены на один лист, закреплена шапка, установлены разрыв листа и печать заголовков, добавлены формулы для расчета отработанных и пропущенных дней, часов.
Добавлен лист "Часы" (норма рабочих часов в день на ставку по должностям), на ячейки которого ссылаются формулы с листа "Табель", его можно скрыть. При ссылках на ячейки листа "Часы" следует добавлять символ $ перед значениями столбца и строки для закрепления адреса ячейки при копировании формул.

Титульный лист:

Количество рабочих дней в месяце может рассчитываться по формуле:
=ЧИСТРАБДНИ(ДАТА(ГОД(СЕГОДНЯ());МЕСЯЦ(СЕГОДНЯ());1);ДАТА(ГОД(СЕГОДНЯ());МЕСЯЦ(СЕГОДНЯ())+1;1)-1;Праздники20)
где исключаются праздничные дни, указанные где-нибудь в диапазоне, именованном здесь как "Праздники20". Здесь нужно вручную забить все праздничные и нерабочие дни года из производственного календаря

Табель подписывается последним числом месяца:  =ДАТА(ГОД(СЕГОДНЯ());МЕСЯЦ(СЕГОДНЯ())+1;0)
- получаем 30, 31 или 28(29) число месяца.

Текущий месяц высчитывается по формуле: 
=ВПР(МЕСЯЦ(СЕГОДНЯ());{1;"января":2;"февраля":3;"марта":4;"апреля":5;"мая":6;"июня":7;"июля":8;"августа":9;"сентября":
10;"октября":11;"ноября":12;"декабря"};2;)
В формуле прописываем нужное окончание месяца (январЬ или январЯ).

Последние две цифры текущего года: 
=ДАТА(ГОД(СЕГОДНЯ());МЕСЯЦ(СЕГОДНЯ())+1;0)

Полностью дата (последнее число текущего месяца текущего года): 
=КОНМЕСЯЦА(СЕГОДНЯ();0)

или, если требуется именно последний РАБОЧИЙ день, исключая праздничные/нерабочие дни: =РАБДЕНЬ(КОНМЕСЯЦА(СЕГОДНЯ();0)+1;-1;Праздники2020)

Лист "Табель"

Диапазон столбцов "Отметки о неявках на работу по числам месяца":
отработанные дни - пустые ячейки. Вручную проставляем выходные - В, пропуски: А - свой счет, Б - болезнь, О и ОУ - отпуска; 0 (ноль часов) - уволился или устроился не с начала месяца.
Диапазон столбцов "Отработано за":
за половину месяца отработанные дни рассчитываются по формуле: 
=СЧИТАТЬПУСТОТЫ(AW10:BL10)
То есть считаем пустые ячейки в диапазоне AW10:BL10 дней половины месяца;

отработанные часы считаем по формуле:
=BM10*часы!$AO$10
, где BM10- адрес ячейки с отработанными днями за полмесяца, который умножаем на часы!$AO$10 - адрес ячейки на листе "часы", где указана норма часов в день по должности. В адрес ячейки добавляем знак $ для закрепления адреса при копировании формулы.

За месяц количество отработанных дней получаем простым сложением отработанных дней за две половины месяца, например: 
=BM10+BM12
, где BM10 и BM12 - адреса ячеек с количеством отработанных дней за первую и вторую половины месяца.

Количество отработанных часов за месяц можно получить, складывая часы за полмесяца: 
=BM11+BM13
, или умножая количество отработанных дней на норму часов в день по должности с листа "часы": 
=BX18*часы!$AO$34.

Заполнение диапазона столбцов "Неявки за месяц":

Формулой 
=ЕСЛИ(СУММ(СЧЁТЕСЛИ(AW10:BL10;{"ОУ";"Б";"А";"О";0}))=0;"";СУММ(СЧЁТЕСЛИ(AW10:BL10;
{"ОУ";"Б";"А";"О";0})))
считаем пропущенные рабочие дни,

а формулой 
=ЕСЛИ(СУММ(СЧЁТЕСЛИ(AW10:BL10;{"ОУ";"Б";"А";"О";0}))=0;"";СУММ(СЧЁТЕСЛИ(AW10:BL10;
{"ОУ";"Б";"А";"О";0}))*часы!$AO$10)
считаем пропущенные рабочие часы.

Аналогично считаем пропущенные педагогические рабочие дни и часы. 
В данных формулах подсчитываем количество ячеек с обозначениями пропусков: (см. условные обозначения на титульном листе) О, ОУ, А или Б:
СЧЁТЕСЛИ(AW10:BL10;{"ОУ";"Б";"А";"О"})
Если в учреждении встречаются другие виды пропусков, можно добавить их обозначения в формулу через запятую.

P.S. Если вдруг человек увольняется или поступает на работу посреди месяца (ставим ноль в табеле), добавляем 0 (ноль) в перечень условных обозначений: {"ОУ";"Б";"А";"О";0}.

В этих же формулах решаем проблему с отображением на листе нулевых значений, то есть, чтобы не выводился "0,00", если у сотрудника нет пропусков. Задаем условие: если количество ячеек с данными в виде О, ОУ, А или Б равно нулю, то в ячейке с формулой не выводятся никакие данные (двойные кавычки "" в формуле), иначе выводится число пропусков. Важно: в формуле не прописываем выходные (В), чтобы они не считались неявками.

Количество пропущенных дней и часов у декретниц вычисляем формулой аналогично подсчету рабочих дней у других сотрудников, устанавливая только для первой декретницы количество пропущенных дней за полмесяца.

Подсчет часов и дней замещения логично автоматизировать только у сотрудников, кому увеличение объема работ или совмещение установлено по приказу на срок тарификации (в примере это машинист по стирке, рабочий по КОРЗ за работу на несколько зданий). Не систематические замещения кратковременно отсутствующих сотрудников высчитывать формулами смысла нет.

P/S На момент публикации (январь 2018г.) в образце приведен пример табеля за февраль 2018 года, но на титульном листе даты выводятся январские, а количество рабочих дней взято с листа "табель" за февраль. Соответственно, в каком месяце вы скачаете данный файл, такие даты на титульном листе у вас и будут, т.к. задействована формула СЕГОДНЯ(), но наполнение листа "табель" не изменится.

Создать копию файла в GoogleSheets

При загрузке на гугл-диск все формулы переносятся и работают отлично, кроме формул для подсчета пропущенных дней и часов. Считает только значение, которое прописано в формуле первым, в данном случае это "ОУ".

Формула подсчета нескольких значений тоже не работает:

=IF(SUM(COUNTIFS(AW10:BL10;"ОУ";AW10:BL10;"Б";AW10:BL10;"А";AW10:BL10;"О"))=0;"";
SUM(COUNTIFS(AW10:BL10;"ОУ";AW10:BL10;"Б";AW10:BL10;"А";AW10:BL10;"О")))

Заработала формула только в таком виде:

=ЕСЛИ(СУММ(СЧЁТЕСЛИ(AW10:BL10;"ОУ");СЧЁТЕСЛИ(AW10:BL10;"Б");СЧЁТЕСЛИ(AW10:BL10;"А");
СЧЁТЕСЛИ(AW10:BL10;"О"))=0;"";СУММ(СЧЁТЕСЛИ(AW10:BL10;"ОУ");СЧЁТЕСЛИ(AW10:BL10;"Б");
СЧЁТЕСЛИ(AW10:BL10;"А");СЧЁТЕСЛИ(AW10:BL10;"О")))
то есть, каждое значение неявки считать отдельно.

Ваши замечания и предложения прошу оставлять в комментариях.